ca0e9badd1
Add a user-space selftest of x86 instruction decoder at kernel build time. When CONFIG_X86_DECODER_SELFTEST=y, Kbuild builds a test harness of x86 instruction decoder and performs it after building vmlinux. The test compares the results of objdump and x86 instruction decoder code and check there are no differences. Signed-off-by: Masami Hiramatsu <mhiramat@redhat.com> Signed-off-by: Jim Keniston <jkenisto@us.ibm.com> Cc: Ananth N Mavinakayanahalli <ananth@in.ibm.com> Cc: Avi Kivity <avi@redhat.com> Cc: Andi Kleen <ak@linux.intel.com> Cc: Christoph Hellwig <hch@infradead.org> Cc: Frank Ch. Eigler <fche@redhat.com> Cc: H. Peter Anvin <hpa@zytor.com> Cc: Ingo Molnar <mingo@elte.hu> Cc: Jason Baron <jbaron@redhat.com> Cc: K.Prasad <prasad@linux.vnet.ibm.com> Cc: Lai Jiangshan <laijs@cn.fujitsu.com> Cc: Li Zefan <lizf@cn.fujitsu.com> Cc: Przemysław Pawełczyk <przemyslaw@pawelczyk.it> Cc: Roland McGrath <roland@redhat.com> Cc: Sam Ravnborg <sam@ravnborg.org> Cc: Srikar Dronamraju <srikar@linux.vnet.ibm.com> Cc: Steven Rostedt <rostedt@goodmis.org> Cc: Tom Zanussi <tzanussi@gmail.com> Cc: Vegard Nossum <vegard.nossum@gmail.com> LKML-Reference: <20090813203421.31965.29006.stgit@localhost.localdomain> Signed-off-by: Frederic Weisbecker <fweisbec@gmail.com>
43 lines
1.2 KiB
Awk
43 lines
1.2 KiB
Awk
#!/bin/awk -f
|
|
# Usage: objdump -d a.out | awk -f distill.awk | ./test_get_len
|
|
# Distills the disassembly as follows:
|
|
# - Removes all lines except the disassembled instructions.
|
|
# - For instructions that exceed 1 line (7 bytes), crams all the hex bytes
|
|
# into a single line.
|
|
# - Remove bad(or prefix only) instructions
|
|
|
|
BEGIN {
|
|
prev_addr = ""
|
|
prev_hex = ""
|
|
prev_mnemonic = ""
|
|
bad_expr = "(\\(bad\\)|^rex|^.byte|^rep(z|nz)$|^lock$|^es$|^cs$|^ss$|^ds$|^fs$|^gs$|^data(16|32)$|^addr(16|32|64))"
|
|
fwait_expr = "^9b "
|
|
fwait_str="9b\tfwait"
|
|
}
|
|
|
|
/^ *[0-9a-f]+:/ {
|
|
if (split($0, field, "\t") < 3) {
|
|
# This is a continuation of the same insn.
|
|
prev_hex = prev_hex field[2]
|
|
} else {
|
|
# Skip bad instructions
|
|
if (match(prev_mnemonic, bad_expr))
|
|
prev_addr = ""
|
|
# Split fwait from other f* instructions
|
|
if (match(prev_hex, fwait_expr) && prev_mnemonic != "fwait") {
|
|
printf "%s\t%s\n", prev_addr, fwait_str
|
|
sub(fwait_expr, "", prev_hex)
|
|
}
|
|
if (prev_addr != "")
|
|
printf "%s\t%s\t%s\n", prev_addr, prev_hex, prev_mnemonic
|
|
prev_addr = field[1]
|
|
prev_hex = field[2]
|
|
prev_mnemonic = field[3]
|
|
}
|
|
}
|
|
|
|
END {
|
|
if (prev_addr != "")
|
|
printf "%s\t%s\t%s\n", prev_addr, prev_hex, prev_mnemonic
|
|
}
|